@echo off
REM Install Node.js 16.20.2 from a bundled MSI.
REM Picks x64 or x86 based on the Windows architecture.
chcp 65001 >nul

setlocal
cd /d "%~dp0"

if exist "%ProgramFiles%\nodejs\node.exe" (
  echo Node.js уже установлен в %ProgramFiles%\nodejs.
  echo Пропускаем установку.
  goto :done
)
if exist "%ProgramFiles(x86)%\nodejs\node.exe" (
  echo Node.js уже установлен в %ProgramFiles(x86)%\nodejs.
  echo Пропускаем установку.
  goto :done
)

set "MSI=node-v16.20.2-x64.msi"
if /i "%PROCESSOR_ARCHITECTURE%"=="x86" if not defined PROCESSOR_ARCHITEW6432 set "MSI=node-v16.20.2-x86.msi"

if not exist "%MSI%" (
  echo Ошибка: файл %MSI% не найден рядом с install.bat.
  echo Убедитесь, что архив распакован полностью.
  pause
  exit /b 1
)

echo Устанавливаем Node.js (%MSI%)...
echo Откроется стандартный установщик Windows — нажмите "Далее" до конца.
msiexec /i "%~dp0%MSI%"
if errorlevel 1 (
  echo Установка Node.js завершилась с ошибкой.
  pause
  exit /b 1
)

:done
echo.
echo Готово. Закройте это окно и запустите start.bat.
pause
endlocal
